[Setup]
AppName=MonSoft
AppVerName=MonSoft 2.0
AppPublisher=Vous
AppPublisherURL=http://www.MonSoft.com
AppSupportURL=http://www.MonSoft.com/support
AppUpdatesURL=http://www.MonSoft.com/download
AppMutex=MonSoft
DefaultDirName={pf}\MonSoft
DefaultGroupName=MonSoft
ExtraDiskSpaceRequired=26214400
MinVersion=4.0.1111,4.0sp6
OutputBaseFilename=Install
OutputDir=Racine CD
PrivilegesRequired=admin
ShowLanguageDialog=Yes
SolidCompression=Yes
Compression=bzip
UninstallDisplayIcon={app}\icon\IconMonSoft.ico
UserInfoPage=Yes
UsePreviousUserInfo=No
DefaultUserInfoName=
DefaultUserInfoOrg=
WizardImageFile=MonSoft\images\MonImage.bmp

[Languages]
Name: "en"; MessagesFile: "compiler:Default.isl,Msg-MonSoft-en.isl"; LicenseFile: "MonSoft\licences\Licen_en.txt"
Name: "fr"; MessagesFile: "French-x-4.0.0.isl,Msg-MonSoft-fr.isl"; LicenseFile: "MonSoft\licences\Licen_fr.txt"

[Messages]
SelectLanguageTitle=MonSoft
SelectLanguageLabel=Sélectionnez la langue à utiliser durant l'installation / Select the language to use during the installation:

[Code]
var
  Chemin: string;
  Chemin1: string;
  Chemin2: string;

  Quest_Acrobat_posee: boolean;
  Rep_utilisateur: integer;
  Rep_Acrobat: boolean;

function OK_Acrobat(): boolean;
begin
  if not Quest_Acrobat_posee then begin
    Quest_Acrobat_posee := true;
    Chemin1 := '';
    Chemin2 := '';
    RegQueryStringValue(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Acrobat.exe', '', Chemin1 );
    RegQueryStringValue(HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Acrord32.exe', '', Chemin2 );
    Chemin := Chemin1+Chemin2 ;
    if ( Chemin = '' ) then begin
      case ActiveLanguage of
        'fr':
          Rep_utilisateur := MsgBox('Pour imprimer les cartes détaillées de MonSoft, il est nécessaire qu''Acrobat Reader soit installé. Or, aucune version de ce logiciel n''a été détectée sur votre PC.' #13 'Voulez vous installer Acrobat Reader 5.05 ?', mbInformation, MB_YESNO);
        'en':
          Rep_utilisateur := MsgBox('To print the MonSoft detailed cards, Acrobat Reader must be installed. Unfortunately no copy of this software has been detected on your PC.' #13 'Do you want to install Acrobat Reader 5.05 ?', mbInformation, MB_YESNO);
      end;

      if Rep_utilisateur = idYes
      then begin
        result := True;     // = on installe
      end else begin
        result := False;    // = on n'installe pas - l'utilisateur ne veut pas
      end;
    end else begin
      result := False;      // = on n'installe pas - Acrobat et/ou Reader déjà présent
    end;
    Rep_Acrobat := result;
  end else begin
    result := Rep_Acrobat;
  end;
end;

[Tasks]
Name: "desktopicon"; Description: "Créer un icône sur le &bureau"; GroupDescription: "Icône(s) supplémentaire(s) :"; Languages: fr
Name: "desktopicon"; Description: "Create a &desktop icon"; GroupDescription: "Additional icons:"; Languages: en

Name: "quicklaunchicon"; Description: "Create a &Quick Launch icon"; GroupDescription: "Additional icons:"; Flags: unchecked; Languages: en
Name: "quicklaunchicon"; Description: "Créer un icône dans la barre de &lancement rapide"; GroupDescription: "Icône(s) supplémentaire(s) :"; Flags: unchecked; Languages: fr

[Icons]
Name: "{group}\MonSoft 2.0"; Filename: "{app}\MonSoft.exe"; WorkingDir: "{app}"; IconFilename: "{app}\icon\IconMonSoft.ico"

Name: "{group}\Release notes"; Filename: "{app}\readme\ReadMe.txt"; Languages: en
Name: "{group}\Notes de version"; Filename: "{app}\readme\LisezMoi.txt"; Languages: fr
Name: "{group}\MonSoft"; Filename: "{app}\MonSoft.url"

Name: "{userdesktop}\MonSoft 2.0"; Filename: "{app}\MonSoft.exe"; WorkingDir: "{app}"; IconFilename: "{app}\icon\IconMonSoft.ico"; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\MonSoft 2.0"; Filename: "{app}\MonSoft.exe"; WorkingDir: "{app}"; IconFilename: "{app}\icon\IconMonSoft.ico"; Tasks: quicklaunchicon

[INI]
Filename: "{app}\MonSoft.url"; Section: "InternetShortcut"; Key: "URL"; String:http://www.MonSoft.com

Filename: "{app}\ini\instpers.ini"; Section: "InfosSaisies"; Key: "Utilisateur"; String: {userinfoname}
Filename: "{app}\ini\instpers.ini"; Section: "InfosSaisies"; Key: "Organisation"; String: {userinfoorg}
Filename: "{app}\ini\instpers.ini"; Section: "InfosSaisies"; Key: "Langue"; String: {language}

[Files]
Source: "MonSoft\*.*"; DestDir: "{app}"; Flags: ignoreversion

Source: "MonSoft\Priv\*.*"; DestDir: "{app}"; Flags: onlyifdoesntexist uninsneveruninstall

Source: "MonSoft\exe\*.*"; DestDir: "{app}\exe"; Flags: ignoreversion
Source: "MonSoft\fonts\*.*"; DestDir: "{app}\fonts"; Flags: ignoreversion
Source: "MonSoft\help\*.*"; DestDir: "{app}\help"; Flags: ignoreversion
Source: "MonSoft\icon\*.*"; DestDir: "{app}\icon"; Flags: ignoreversion
Source: "MonSoft\images\MonSoft.gif"; DestDir: "{app}\images"; Flags: ignoreversion
Source: "MonSoft\ini\*.*"; DestDir: "{app}\ini"; Flags: ignoreversion
Source: "MonSoft\licences\*.*"; DestDir: "{app}\licences"; Flags: ignoreversion

Source: "MonSoft\fonts\MonSoft.ttf"; DestDir: "{fonts}"; FontInstall: "MonSoft"; Flags: onlyifdoesntexist uninsneveruninstall

; copie des fichiers figurant dans la racine du CD-Rom
; !!! Pour un installeur en version 1 seul fichier, mettez des ; aux lignes ci-dessous !!!
; !!! ----------------------------------------------------------- !!!
Source: "{src}\*.txt"; DestDir: "{app}\readme"; Flags: ignoreversion external
Source: "{src}\Pdf\English\*.*"; DestDir: "{app}\Pdf"; Flags: ignoreversion external
Source: "{src}\Pdf\Francais\*.*"; DestDir: "{app}\Pdf"; Flags: ignoreversion external
; !!! ----------------------------------------------------------- !!!

; !!! Pour un installeur en version 1 seul fichier, enlevez tous les ; des lignes ci-dessous !!!
; !!! ----------------------------------------------------------- !!!
; Source: "Racine CD\*.txt"; DestDir: "{app}\readme"; Flags: ignoreversion
; Source: "Racine CD\Pdf\English\*.*"; DestDir: "{app}\Pdf"; Flags: ignoreversion
; Source: "Racine CD\Pdf\Francais\*.*"; DestDir: "{app}\Pdf"; Flags: ignoreversion
; Source: "Racine CD\AcroRead\English\rp505enu.exe"; DestDir: "{tmp}"; Flags: ignoreversion; Check: OK_Acrobat; Languages: en
; Source: "Racine CD\AcroRead\Francais\rp505fra.exe"; DestDir: "{tmp}"; Flags: ignoreversion; Check: OK_Acrobat; Languages: fr
; !!! ----------------------------------------------------------- !!!

[Run]
; Installation d'Acrobat Reader si validé par la fonction OK_Acrobat
; !!! Pour un installeur en version 1 seul fichier, passez les 2 ; sur les 1ère et 2ème lignes ci-dessous !!!
; !!! ----------------------------------------------------------- !!!
Filename: "{src}\AcroRead\English\rp505enu.exe"; StatusMsg: "Acrobat Reader 5.05 installation..."; Check: OK_Acrobat; Languages: en
Filename: "{src}\AcroRead\Francais\rp505fra.exe"; StatusMsg: "Installation d'Acrobat Reader 5.05..."; Check: OK_Acrobat; Languages: fr

; Filename: "{tmp}\rp505enu.exe"; StatusMsg: "Acrobat Reader 5.05 setup..."; Check: OK_Acrobat; Languages: en
; Filename: "{tmp}\rp505fra.exe"; StatusMsg: "Installation d'Acrobat Reader 5.05..."; Check: OK_Acrobat; Languages: fr
; !!! ----------------------------------------------------------- !!!

Filename: "{app}\ReadMe\ReadMe.txt"; Description: "View ReadMe.txt file"; Flags: shellexec postinstall skipifsilent; Languages: en
Filename: "{app}\ReadMe\LisezMoi.txt"; Description: "Voir fichier LisezMoi.txt"; Flags: shellexec postinstall skipifsilent; Languages: fr

[UninstallDelete]
Type: files; Name: "{app}\MonSoft.url"
Type: files; Name: "{app}\*.bak"
Type: files; Name: "{app}\ini\instpers.ini"
Type: files; Name: "{app}\help\*.gid"